Originally, there was an issue with these two new fields in that they would only accept values in the form of "1:12,123" which has since been fixed to also accept values in the form of "1:12.123". However, despite accepting the latter value, it won't display as such even for languages which use that numbering standard (in this case, English here in the States). It's not a major issue, but it does annoy me a tad when I scan over this field and see it in the form of "1:12,123".
While on the subject of these two new fields, I think a nice addition would be check boxes that would allow you to easily enable and disable the values. Granted, if you want the track to play in full, you can just delete the values and they'll go back to the default (being the beginning and end of the song). However, it would be nice to be able to enable full playback on certain tracks, while also retaining previously set times (as there may be a track where you often only want to hear a specific verse or such, while other times you would like to hear it in full. I wouldn't want to have to re-add the values for that specific verse all the time. You know?)
Start/Stop time annoyance
Moderator: Gurus
-
- Posts: 2283
- Joined: Tue Aug 29, 2006 1:09 pm
- Location: Kansas City, Missouri, United States
Re: Start/Stop time annoyance
And an option under Tools > Options > Playback Rules to be able to enable/disable start/stop time per Type and a global option under the Play menu.
Download MediaMonkey | License
Help: Knowledge Base | MediaMonkey for Windows 5 | MediaMonkey for Android
Lowlander (MediaMonkey user since 2003)
Help: Knowledge Base | MediaMonkey for Windows 5 | MediaMonkey for Android
Lowlander (MediaMonkey user since 2003)
Re: Start/Stop time annoyance
Thanks.
Re. the formatting issue, added as: http://www.ventismedia.com/mantis/view.php?id=8343
Re. the other suggestions, I'm copying this to the wishlist for review post 4.0.
-Rusty
Re. the formatting issue, added as: http://www.ventismedia.com/mantis/view.php?id=8343
Re. the other suggestions, I'm copying this to the wishlist for review post 4.0.
-Rusty
Re: Start/Stop time annoyance
I second that! Would be greatLowlander wrote:And an option under Tools > Options > Playback Rules to be able to enable/disable start/stop time per Type and a global option under the Play menu.
Re: Start/Stop time annoyance
Hi, I'm just wondering what was the status of this.rusty wrote: Re. the other suggestions, I'm copying this to the wishlist for review post 4.0.
-Rusty
When I seconded this feature I didn't elaborate. In my case, I'd love to specify start/end time on tracks to bypass slow intros/outros for parties. But when listening to music by myself I usually want to hear the whole track. So a switch to consider start/end time, global or by type, would be great. Without that, I'm not going to use start/end time.
Re: Start/Stop time annoyance
Hi! 4.1 beta is out and still no sign of this. What are the chances of seeing this option appear in the near future?rycher wrote:Hi, I'm just wondering what was the status of this.rusty wrote: Re. the other suggestions, I'm copying this to the wishlist for review post 4.0.
-Rusty
When I seconded this feature I didn't elaborate. In my case, I'd love to specify start/end time on tracks to bypass slow intros/outros for parties. But when listening to music by myself I usually want to hear the whole track. So a switch to consider start/end time, global or by type, would be great. Without that, I'm not going to use start/end time.
Cheers!
Re: Start/Stop time annoyance
While a switch to turn on or off considering the start and stop times specified would be more user-friendly, since it does not seem to be coming I've developed a work-around with 2 scripts using the custom field 5.
One script copies the start and stop times to custom field 5 and resets the start and stop times to the default:
The other script copies back the start and stop times from custom 5:
So you just need to use those to switch between using custom or default start/stop times.
Cheers!
One script copies the start and stop times to custom field 5 and resets the start and stop times to the default:
Code: Select all
'=============================================================================================
'
' MediaMonkey Script
'
' NAME: Move start and stop times to Custom 5 field.
'
' AUTHOR: Tanguy Kervahut
' DATE : 13/02/2014
'
' INSTALL: Copy to Scripts directory and add the following to Scripts.ini
' Don't forget to remove comments (') and set the order appropriately
'
' [MoveTimeToCustom5]
' FileName=MoveTimeToCustom5.vbs
' ProcName=MoveTimeToCustom5
' Order=15
' DisplayName=&Move out start/stop time (normal)
' Description=Move out start and stop time to custom 5 field
' Language=VBScript
' ScriptType=0
'
'=============================================================================================
Sub MoveTimeToCustom5
' Get list of tracks having specific start or stop time
Dim list : Set list = SDB.NewSongList
Dim Iter : Set Iter = SDB.Database.QuerySongs("Songs.StartTime > 0 OR (Songs.StopTime > 0 AND Songs.StopTime < Songs.SongLength)")
Do While Not Iter.EOF
list.Add( Iter.Item )
Iter.Next
Loop
If list.Count = 0 Then
Call SDB.MessageBox("No tracks with start/stop time to move.",mtInformation,Array(mbOk))
Exit Sub
else
Call SDB.MessageBox("Nb tracks with start/stop time to move out: " & list.Count,mtInformation,Array(mbOk))
End If
' Define variables
Dim i, CurSong
' Process tracks
For i=0 To list.count-1
Set CurSong = list.Item(i)
CurSong.Custom5 = CStr(CurSong.StartTime) +"_"+ CStr(CurSong.StopTime)
CurSong.StartTime = 0
CurSong.StopTime = CurSong.SongLength
Next
' Write all back to DB and update tags
list.UpdateAll
End Sub
Code: Select all
'=============================================================================================
'
' MediaMonkey Script
'
' NAME: Move Custom 5 field value to start and stop time.
'
' AUTHOR: Tanguy Kervahut
' DATE : 13/02/2014
'
' INSTALL: Copy to Scripts directory and add the following to Scripts.ini
' Don't forget to remove comments (') and set the order appropriately
'
' [MoveCustom5ToTime]
' FileName=MoveCustom5ToTime.vbs
' ProcName=MoveCustom5ToTime
' Order=15
' DisplayName=&Move in start/stop time (party)
' Description=Move in start and stop time from custom 5 field
' Language=VBScript
' ScriptType=0
'
'=============================================================================================
Sub MoveCustom5ToTime
' Get list of tracks with a value in Custom 5
Dim list : Set list = SDB.NewSongList
Dim Iter : Set Iter = SDB.Database.QuerySongs("Songs.Custom5 <> ''")
Do While Not Iter.EOF
list.Add( Iter.Item )
Iter.Next
Loop
If list.Count = 0 Then
Call SDB.MessageBox("No tracks with value in Custom 5.",mtInformation,Array(mbOk))
Exit Sub
else
Call SDB.MessageBox("Nb tracks with start/stop time to move in: " & list.Count,mtInformation,Array(mbOk))
End If
' Define variables
Dim i, CurSong, SepPos
' Process tracks
For i=0 To list.count-1
Set CurSong = list.Item(i)
SepPos = InStr(CurSong.Custom5, "_")
if SepPos > 0 Then
CurSong.StartTime = CLng(Left(CurSong.Custom5,SepPos-1))
CurSong.StopTime = CLng(Right(CurSong.Custom5,Len(CurSong.Custom5)-SepPos))
' CurSong.Custom5 = ""
End If
Next
' Write all back to DB and update tags
list.UpdateAll
End Sub
Cheers!